1 files changed, 86 insertions, 0 deletions
diff --git a/autofoo-efl/configure.ac b/autofoo-efl/configure.ac
new file mode 100644
index 0000000..ac070f7
--- /dev/null
+++ b/autofoo-efl/configure.ac
@@ -0,0 +1,86 @@
+dnl Process this file with autoconf to produce a configure script.
+
+# get rid of that stupid cache mechanism
+rm -f config.cache
+
+AC_INIT([autofoo-efl], [0.1.0], [jeremy@asynk.ch])
+AC_PREREQ([2.60])
+AC_CONFIG_SRCDIR([configure.ac])
+AC_CONFIG_MACRO_DIR([m4])
+
+AC_CONFIG_HEADERS([autofoo_efl_config.h])
+
+AM_INIT_AUTOMAKE([1.6 dist-bzip2])
+m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
+
+AC_USE_SYSTEM_EXTENSIONS
+AM_PROG_CC_STDC
+AM_PROG_CC_C_O
+AC_C___ATTRIBUTE__
+
+requirements="\
+   elementary >= 1.7.0 \
+   eina >= 1.7.0 \
+   eet >= 1.7.0 \
+   evas >= 1.7.0 \
+   ecore >= 1.7.0 \
+   edje >= 1.7.0 \
+   "
+
+PKG_CHECK_MODULES([AUTOFOO_EFL], [${requirements}])
+
+EFL_WITH_BIN([edje], [edje-cc], [edje_cc])
+
+with_max_log_level="EINA_LOG_LEVEL_ERR"
+AC_ARG_WITH(maximum-log-level,
+   [AC_HELP_STRING([--with-maximum-log-level=NUMBER],
+                   [limit autofoo-efl log level to the given number, any call to EINA_LOG() with values greater than this will be compiled out, ignoring runtime settings, but saving function calls.])],
+   [
+    if test "x${withval}" != "xno"; then
+       if echo "${withval}" | grep -E '^[[0-9]]+$' >/dev/null 2>/dev/null; then
+          AC_MSG_NOTICE([ignoring any EINA_LOG() with level greater than ${withval}])
+          with_max_log_level="${withval}"
+       else
+          AC_MSG_ERROR([--with-maximum-log-level takes a decimal number, got "${withval}" instead.])
+       fi
+    fi
+    ], [:])
+
+AC_DEFINE_UNQUOTED(EINA_LOG_LEVEL_MAXIMUM, ${with_max_log_level}, [if set, logging is limited to this amount.])
+
+AC_CONFIG_FILES([
+Makefile
+src/Makefile
+src/bin/Makefile
+data/Makefile
+data/desktop/Makefile
+data/icons/Makefile
+data/images/Makefile
+data/fonts/Makefile
+data/themes/Makefile
+data/themes/images/Makefile
+])
+
+AC_OUTPUT
+
+#####################################################################
+## Info
+
+echo
+echo
+echo
+echo "------------------------------------------------------------------------"
+echo "$PACKAGE $VERSION"
+echo "------------------------------------------------------------------------"
+echo
+echo "Configuration Options Summary:"
+echo "  EINA_LOG() max level.....: $with_max_log_level"
+echo
+echo "Compilation................: make (or gmake)"
+echo "  CPPFLAGS.................: $CPPFLAGS"
+echo "  CFLAGS...................: $CFLAGS"
+echo "  LDFLAGS..................: $LDFLAGS"
+echo
+echo "Installation...............: make install (as root if needed, with 'su' or 'sudo')"
+echo "  prefix...................: $prefix"
+echo